constant function Revival_BaseTime takes nothing returns real
    return 30.00 // The base waiting time.
endfunction

constant function Revival_LevelMultiply takes nothing returns real
    return 0.00 // Adds the heroes level to the time with a multiplier.
    // E.g. return 1 will cause heroes to wait basetime + the hero's level + distance.
    // Return 2 will cause basetime + hero's level * 2 + distance and so on...
endfunction

constant function Revival_DistMultiply takes nothing returns real
    return 0.00 // Will add more time the futher away the hero dies from revival point.
    // Return 0 will remove the add distance time.
    // Return 1 will simply add the distance to the time. E.g. a unit is 400 units away from revival point means it will add 400 seconds to the time.
    // So try keep it low (Like 0.002).
endfunction

constant function Revival_ShowBeam takes nothing returns boolean
    return true // Show revival beam.
endfunction

constant function Revival_X takes nothing returns real
    return -145.00 // X coord of revival.
endfunction

constant function Revival_Y takes nothing returns real
    return -3811.00 // Y coord of revival.
endfunction
  
function Revival_Cond takes nothing returns boolean
    return (IsUnitType(GetTriggerUnit(), UNIT_TYPE_HERO) and GetPlayerController(GetOwningPlayer(GetTriggerUnit())) == MAP_CONTROL_USER)
    // Is the dying unit a hero and owned by a player then return true
endfunction
  
function Revival_MainFunc takes nothing returns nothing
    local unit hero = GetTriggerUnit() // Get dying hero
    local real x = GetUnitX(hero) - Revival_X() // Get x distance from revival point to hero x.
    local real y = GetUnitY(hero) - Revival_Y() // Get y distance from revival point to hero y.
    local real sleepTime = Revival_BaseTime() + (Revival_LevelMultiply() * GetHeroLevel(hero)) + (Revival_DistMultiply() * SquareRoot((x * x) + (y * y))) // Basetime + ( LevelMultiplier * Hero Level ) + ( DistanceMultiplier * Distance from revival point )
    call PolledWait(sleepTime)
    call ReviveHero( hero, Revival_X(), Revival_Y(), Revival_ShowBeam() )
    set hero = null
endfunction

function InitTrig_Revival takes nothing returns nothing
    local integer index = 0
    set gg_trg_Revival = CreateTrigger( )
    loop
        call TriggerRegisterPlayerUnitEvent(gg_trg_Revival, Player(index), EVENT_PLAYER_UNIT_DEATH, null)
        set index = index + 1
        exitwhen index == bj_MAX_PLAYER_SLOTS
    endloop
    call TriggerAddCondition( gg_trg_Revival, Condition( function Revival_Cond ) )
    call TriggerAddAction( gg_trg_Revival, function Revival_MainFunc )
endfunction